Moved old codebase to old-codebase/

2012-03-07 16:24:50 +01:00
parent e2b367dd56
commit dc1a6d7a0a
377 changed files with 0 additions and 0 deletions
--- a/old-codebase/cnf/.gitignore
+++ b/old-codebase/cnf/.gitignore
@@ -0,0 +1 @@
+autom4te.cache
--- a/old-codebase/cnf/README
+++ b/old-codebase/cnf/README
@@ -0,0 +1,2 @@
+These files are for generating the 'configure' script.  They are useless
+to everyone except for hackers who know how to use GNU autoconf.  JE 28 Oct 97
--- a/old-codebase/cnf/acconfig.h
+++ b/old-codebase/cnf/acconfig.h
@@ -0,0 +1,17 @@
+/* Define if we're compiling CircleMUD under any type of UNIX system.  */
+#undef CIRCLE_UNIX
+
+/* Define if the system is capable of using crypt() to encrypt.  */
+#undef CIRCLE_CRYPT
+
+/* Define if we don't have proper support for the system's crypt().  */
+#undef HAVE_UNSAFE_CRYPT
+
+/* Define is the system has struct in_addr.  */
+#undef HAVE_STRUCT_IN_ADDR
+
+/* Define to `int' if <sys/socket.h> doesn't define.  */
+#undef socklen_t
+
+/* Define to `int' if <sys/types.h> doesn't define.  */
+#undef ssize_t
--- a/old-codebase/cnf/aclocal.m4
+++ b/old-codebase/cnf/aclocal.m4
@@ -0,0 +1,174 @@
+# generated automatically by aclocal 1.11.1 -*- Autoconf -*-
+
+# Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
+# 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY, to the extent permitted by law; without
+# even the implied warranty of MERCHANTABILITY or FITNESS FOR A
+# PARTICULAR PURPOSE.
+
+# pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
+# serial 1 (pkg-config-0.24)
+# 
+# Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+#
+# As a special exception to the GNU General Public License, if you
+# distribute this file as part of a program that contains a
+# configuration script generated by Autoconf, you may include it under
+# the same distribution terms that you use for the rest of that program.
+
+# PKG_PROG_PKG_CONFIG([MIN-VERSION])
+# ----------------------------------
+AC_DEFUN([PKG_PROG_PKG_CONFIG],
+[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
+m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$])
+m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$])
+AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])
+AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path])
+AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path])
+
+if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
+	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
+fi
+if test -n "$PKG_CONFIG"; then
+	_pkg_min_version=m4_default([$1], [0.9.0])
+	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
+	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
+		AC_MSG_RESULT([yes])
+	else
+		AC_MSG_RESULT([no])
+		PKG_CONFIG=""
+	fi
+fi[]dnl
+])# PKG_PROG_PKG_CONFIG
+
+# PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+#
+# Check to see whether a particular set of modules exists.  Similar
+# to PKG_CHECK_MODULES(), but does not set variables or print errors.
+#
+# Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+# only at the first occurence in configure.ac, so if the first place
+# it's called might be skipped (such as if it is within an "if", you
+# have to call PKG_CHECK_EXISTS manually
+# --------------------------------------------------------------
+AC_DEFUN([PKG_CHECK_EXISTS],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+if test -n "$PKG_CONFIG" && \
+    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
+  m4_default([$2], [:])
+m4_ifvaln([$3], [else
+  $3])dnl
+fi])
+
+# _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
+# ---------------------------------------------
+m4_define([_PKG_CONFIG],
+[if test -n "$$1"; then
+    pkg_cv_[]$1="$$1"
+ elif test -n "$PKG_CONFIG"; then
+    PKG_CHECK_EXISTS([$3],
+                     [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`
+		      test "x$?" != "x0" && pkg_failed=yes ],
+		     [pkg_failed=yes])
+ else
+    pkg_failed=untried
+fi[]dnl
+])# _PKG_CONFIG
+
+# _PKG_SHORT_ERRORS_SUPPORTED
+# -----------------------------
+AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
+        _pkg_short_errors_supported=yes
+else
+        _pkg_short_errors_supported=no
+fi[]dnl
+])# _PKG_SHORT_ERRORS_SUPPORTED
+
+
+# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+# [ACTION-IF-NOT-FOUND])
+#
+#
+# Note that if there is a possibility the first call to
+# PKG_CHECK_MODULES might not happen, you should be sure to include an
+# explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
+#
+#
+# --------------------------------------------------------------
+AC_DEFUN([PKG_CHECK_MODULES],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
+AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
+
+pkg_failed=no
+AC_MSG_CHECKING([for $1])
+
+_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
+_PKG_CONFIG([$1][_LIBS], [libs], [$2])
+
+m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
+and $1[]_LIBS to avoid the need to call pkg-config.
+See the pkg-config man page for more details.])
+
+if test $pkg_failed = yes; then
+   	AC_MSG_RESULT([no])
+        _PKG_SHORT_ERRORS_SUPPORTED
+        if test $_pkg_short_errors_supported = yes; then
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2" 2>&1`
+        else 
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1`
+        fi
+	# Put the nasty error message in config.log where it belongs
+	echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
+
+	m4_default([$4], [AC_MSG_ERROR(
+[Package requirements ($2) were not met:
+
+$$1_PKG_ERRORS
+
+Consider adjusting the PKG_CONFIG_PATH environment variable if you
+installed software in a non-standard prefix.
+
+_PKG_TEXT])[]dnl
+        ])
+elif test $pkg_failed = untried; then
+     	AC_MSG_RESULT([no])
+	m4_default([$4], [AC_MSG_FAILURE(
+[The pkg-config script could not be found or is too old.  Make sure it
+is in your PATH or set the PKG_CONFIG environment variable to the full
+path to pkg-config.
+
+_PKG_TEXT
+
+To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl
+        ])
+else
+	$1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
+	$1[]_LIBS=$pkg_cv_[]$1[]_LIBS
+        AC_MSG_RESULT([yes])
+	$3
+fi[]dnl
+])# PKG_CHECK_MODULES
+
+m4_include([local.m4])
--- a/old-codebase/cnf/autogen.sh
+++ b/old-codebase/cnf/autogen.sh
@@ -0,0 +1,2 @@
+aclocal -I .
+autoconf
--- a/old-codebase/cnf/configure.in
+++ b/old-codebase/cnf/configure.in
@@ -0,0 +1,220 @@
+dnl Process this file with autoconf to produce a configure script.
+AC_INIT(src/act.comm.c)
+AC_CONFIG_MACRO_DIR([.])
+AC_SUBST(MYFLAGS)
+AC_SUBST(NETLIB)
+AC_SUBST(CRYPTLIB)
+
+AC_CONFIG_HEADER(src/conf.h)
+AC_DEFINE(CIRCLE_UNIX)
+
+dnl Find the 'more' program
+AC_CHECK_PROGS(MORE, less most more cat)
+
+dnl Checks for programs.
+AC_PROG_CC
+
+dnl If we're using gcc, use gcc options.
+dnl If not, test for various common switches to make a 'cc' compiler
+dnl compile ANSI C code.
+if test $ac_cv_prog_gcc = yes; then
+
+  dnl Determine if gcc -Wall causes warnings on isascii(), etc.
+  AC_CACHE_CHECK(whether ${CC-cc} -Wall also needs -Wno-char-subscripts,
+	ac_cv_char_warn,
+  [
+    OLDCFLAGS=$CFLAGS
+    CFLAGS="$CFLAGS -Wall -Werror"
+    AC_TRY_COMPILE([#include <ctype.h>],
+       [ int i; char c = '0';
+         i = isascii(c);
+         i = isdigit(c);
+         i = isprint(c);
+       ], ac_cv_char_warn=no, ac_cv_char_warn=yes)
+    CFLAGS=$OLDCFLAGS
+  ])
+
+  dnl If Determine if gcc can accept -Wno-char-subscripts
+  AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-char-subscripts, ac_cv_gcc_ncs,
+  [
+    OLDCFLAGS=$CFLAGS
+    CFLAGS="$CFLAGS -Wno-char-subscripts"
+    AC_TRY_COMPILE(, , ac_cv_gcc_ncs=yes, ac_cv_gcc_ncs=no)
+    CFLAGS=$OLDCFLAGS
+  ])
+
+  dnl If Determine if gcc can accept -fno-builtin
+  AC_CACHE_CHECK(whether ${CC-cc} accepts -fno-builtin, ac_cv_gcc_fnb,
+  [
+    OLDCFLAGS=$CFLAGS
+    CFLAGS="$CFLAGS -fno-builtin"
+    AC_TRY_COMPILE(, , ac_cv_gcc_fnb=yes, ac_cv_gcc_fnb=no)
+    CFLAGS=$OLDCFLAGS
+  ])
+
+  dnl If gcc -Wall gives no warnings with isascii(), use "-Wall";
+  dnl Otherwise, if gcc -Wall gives isascii warnings:
+  dnl    If we can use -Wno-char-subscripts, use "-Wall -Wno-char-subscripts"
+  dnl    If can't use -Wno-char-subscripts, use no flags at all.
+
+  if test ${ac_cv_char_warn:-ERROR} = no; then
+    MYFLAGS="-Wall"
+  else
+    if test ${ac_cv_gcc_ncs:-ERROR} = yes; then
+      MYFLAGS="-Wall -Wno-char-subscripts"
+    else
+      MYFLAGS=""
+    fi
+  fi
+
+else
+  dnl We aren't using gcc so we can't assume any special flags.
+  MYFLAGS=""
+
+fi
+
+dnl Checks for libraries.  We check for the library only if the function is
+dnl not available without the library.
+AC_CHECK_FUNC(gethostbyaddr, ,
+    [AC_CHECK_LIB(nsl, gethostbyaddr, NETLIB="-lnsl $NETLIB")])
+
+AC_CHECK_FUNC(socket, ,
+    [AC_CHECK_LIB(socket, socket, NETLIB="-lsocket $NETLIB")])
+
+AC_CHECK_FUNC(malloc, ,
+    [AC_CHECK_LIB(malloc, malloc)])
+
+AC_CHECK_FUNC(crypt, AC_DEFINE(CIRCLE_CRYPT),
+    [AC_CHECK_LIB(crypt, crypt, AC_DEFINE(CIRCLE_CRYPT) CRYPTLIB="-lcrypt")]
+    )
+
+dnl Checks for header files.
+AC_HEADER_STDC
+AC_HEADER_SYS_WAIT
+AC_CHECK_HEADERS(fcntl.h sys/fcntl.h errno.h net/errno.h string.h strings.h)
+AC_CHECK_HEADERS(limits.h sys/time.h sys/select.h sys/types.h unistd.h)
+AC_CHECK_HEADERS(memory.h crypt.h assert.h arpa/telnet.h arpa/inet.h)
+AC_CHECK_HEADERS(sys/stat.h sys/socket.h sys/resource.h netinet/in.h netdb.h)
+AC_CHECK_HEADERS(signal.h sys/uio.h mcheck.h)
+
+AC_UNSAFE_CRYPT
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_C_CONST
+AC_TYPE_PID_T
+AC_TYPE_SIZE_T
+AC_CHECK_TYPE(ssize_t, int)
+AC_HEADER_TIME
+
+dnl Check for the 'struct in_addr' definition. Ugly, yes.
+if test $ac_cv_header_netinet_in_h = no; then
+  ac_cv_struct_in_addr = no
+else
+  if test $ac_cv_header_sys_types_h = yes; then
+    headers=`cat << EOF
+#include <sys/types.h>
+#include <netinet/in.h>
+EOF
+`
+  else
+    headers="#include <netinet/in.h>"
+  fi
+
+  AC_CACHE_CHECK([for struct in_addr], ac_cv_struct_in_addr,
+    [ AC_TRY_COMPILE([$headers],[struct in_addr tp; tp.s_addr;], ac_cv_struct_in_addr=yes, ac_cv_struct_in_addr=no)])
+
+  if test $ac_cv_struct_in_addr = yes; then
+    AC_DEFINE(HAVE_STRUCT_IN_ADDR)
+  fi
+fi
+
+
+dnl Check for the 'typedef socklen_t' definition. Even uglier, yes.
+if test $ac_cv_header_sys_socket_h = no; then
+  ac_cv_socklen_t = no;
+else
+  AC_CACHE_CHECK([for typedef socklen_t], ac_cv_socklen_t,
+    [ AC_TRY_COMPILE([#include <sys/socket.h>],[socklen_t sl; sl=0;], ac_cv_socklen_t=yes, ac_cv_socklen_t=no)])
+fi
+
+if test $ac_cv_socklen_t = no; then
+  AC_DEFINE(socklen_t, int)
+fi
+
+
+dnl Checks for library functions.
+AC_TYPE_SIGNAL
+AC_FUNC_VPRINTF
+AC_CHECK_FUNCS(gettimeofday select snprintf strcasecmp strdup strerror stricmp strlcpy strncasecmp strnicmp strstr vsnprintf)
+
+dnl Check for functions that parse IP addresses
+ORIGLIBS=$LIBS
+LIBS="$LIBS $NETLIB"
+AC_CHECK_FUNCS(inet_addr inet_aton)
+LIBS=$ORIGLIBS
+
+dnl Check for prototypes
+AC_CHECK_PROTO(accept)
+AC_CHECK_PROTO(atoi)
+AC_CHECK_PROTO(atol)
+AC_CHECK_PROTO(bind)
+AC_CHECK_PROTO(bzero)
+AC_CHECK_PROTO(chdir)
+AC_CHECK_PROTO(close)
+AC_CHECK_PROTO(crypt)
+AC_CHECK_PROTO(fclose)
+AC_CHECK_PROTO(fcntl)
+AC_CHECK_PROTO(fflush)
+AC_CHECK_PROTO(fprintf)
+AC_CHECK_PROTO(fputc)
+AC_CHECK_PROTO(fputs)
+AC_CHECK_PROTO(fread)
+AC_CHECK_PROTO(fscanf)
+AC_CHECK_PROTO(fseek)
+AC_CHECK_PROTO(fwrite)
+AC_CHECK_PROTO(getpeername)
+AC_CHECK_PROTO(getpid)
+AC_CHECK_PROTO(getrlimit)
+AC_CHECK_PROTO(getsockname)
+AC_CHECK_PROTO(gettimeofday)
+AC_CHECK_PROTO(htonl)
+AC_CHECK_PROTO(htons)
+AC_CHECK_PROTO(inet_addr)
+AC_CHECK_PROTO(inet_aton)
+AC_CHECK_PROTO(inet_ntoa)
+AC_CHECK_PROTO(listen)
+AC_CHECK_PROTO(ntohl)
+AC_CHECK_PROTO(perror)
+AC_CHECK_PROTO(printf)
+AC_CHECK_PROTO(qsort)
+AC_CHECK_PROTO(read)
+AC_CHECK_PROTO(remove)
+AC_CHECK_PROTO(rewind)
+AC_CHECK_PROTO(select)
+AC_CHECK_PROTO(setitimer)
+AC_CHECK_PROTO(setrlimit)
+AC_CHECK_PROTO(setsockopt)
+AC_CHECK_PROTO(snprintf)
+AC_CHECK_PROTO(socket)
+AC_CHECK_PROTO(sprintf)
+AC_CHECK_PROTO(sscanf)
+AC_CHECK_PROTO(strcasecmp)
+AC_CHECK_PROTO(strdup)
+AC_CHECK_PROTO(strerror)
+AC_CHECK_PROTO(stricmp)
+AC_CHECK_PROTO(strlcpy)
+AC_CHECK_PROTO(strncasecmp)
+AC_CHECK_PROTO(strnicmp)
+AC_CHECK_PROTO(system)
+AC_CHECK_PROTO(time)
+AC_CHECK_PROTO(unlink)
+AC_CHECK_PROTO(vsnprintf)
+AC_CHECK_PROTO(write)
+
+PKG_CHECK_MODULES([SQLITE3], sqlite3)
+AC_SUBST(SQLITE3_CFLAGS)
+AC_SUBST(SQLITE3_LIBS)
+
+AC_OUTPUT(src/Makefile src/util/Makefile)
+#
+echo "Configuration completed.  To compile, type:  cd src; make"
--- a/old-codebase/cnf/local.m4
+++ b/old-codebase/cnf/local.m4
@@ -0,0 +1,77 @@
+AC_DEFUN(AC_CHECK_PROTO,
+[
+ac_safe=translit($1, './+-', '__p_');
+
+AC_MSG_CHECKING([if $1 is prototyped])
+AC_CACHE_VAL(ac_cv_prototype_$ac_safe, [#
+  if test $ac_cv_gcc_fnb = yes; then
+    OLDCFLAGS=$CFLAGS
+    CFLAGS="$CFLAGS -fno-builtin"
+  fi
+AC_TRY_COMPILE([
+#define NO_LIBRARY_PROTOTYPES
+#define __COMM_C__
+#define __ACT_OTHER_C__
+#include "src/sysdep.h"
+#ifdef $1
+  error - already defined!
+#endif
+void $1(int a, char b, int c, char d, int e, char f, int g, char h);
+],dnl
+,
+eval "ac_cv_prototype_$ac_safe=no",eval "ac_cv_prototype_$ac_safe=yes")
+  if test $ac_cv_gcc_fnb = yes; then
+    CFLAGS=$OLDCFLAGS
+  fi
+])
+
+if eval "test \"`echo '$ac_cv_prototype_'$ac_safe`\" = yes"; then
+  AC_MSG_RESULT(yes)
+else
+  AC_DEFINE(builtin(format, NEED_%s_PROTO, translit($1, 'a-z', 'A-Z')), , Check for a prototype to $1.)
+  AC_MSG_RESULT(no)
+fi
+])
+
+dnl @@@t1="MAKE_PROTO_SAFE($1)"; t2="MAKE_PROTO_NAME($t1)"; literals="$literals $t2"@@@])
+
+
+AC_DEFUN(AC_UNSAFE_CRYPT, [
+  AC_CACHE_CHECK([whether crypt needs over 10 characters], ac_cv_unsafe_crypt, [
+    if test ${ac_cv_header_crypt_h-no} = yes; then
+      use_crypt_header="#include <crypt.h>"
+    fi
+    if test ${ac_cv_lib_crypt_crypt-no} = yes; then
+      ORIGLIBS=$LIBS
+      LIBS="-lcrypt $LIBS"
+    fi
+    AC_TRY_RUN(
+changequote(<<, >>)dnl
+<<
+#define _XOPEN_SOURCE
+#include <string.h>
+#include <unistd.h>
+$use_crypt_header
+
+int main(void)
+{
+  char pwd[11], pwd2[11];
+
+  strncpy(pwd, (char *)crypt("FooBar", "BazQux"), 10);
+  pwd[10] = '\0';
+  strncpy(pwd2, (char *)crypt("xyzzy", "BazQux"), 10);
+  pwd2[10] = '\0';
+  if (strcmp(pwd, pwd2) == 0)
+    exit(0);
+  exit(1);
+}
+>>
+changequote([, ])dnl
+, ac_cv_unsafe_crypt=yes, ac_cv_unsafe_crypt=no, ac_cv_unsafe_crypt=no)])
+if test $ac_cv_unsafe_crypt = yes; then
+  AC_DEFINE(HAVE_UNSAFE_CRYPT)
+fi
+if test ${ac_cv_lib_crypt_crypt-no} = yes; then
+  LIBS=$ORIGLIBS
+fi
+])